ansys

FINISH
/CLEAR, START
*set, d, 2 !扩大基础的长度
/prep7
et,1,solid45

mp,ex,1,30e9 !定义面层参数
mp,prxy,1,0.15

mp,ex,2,1500e6 !定义水泥稳定碎石基层参数
mp,prxy,2,0.2

mp,ex,3,1500e6 !定义二灰稳定碎石底基层参数
mp,prxy,3,0.25

mp,ex,4,600e6 !定义手摆片石垫层参数
mp,prxy,4,0.35

mp,ex,5,40e6 !定义土基参数
mp,prxy,5,0.35

K, 1,-5/2-d,-3.5/2-d,0 !定义建立模型的关键点1
K, 2,-5/2-d,3.5/2+d,0 !定义建立模型的关键点2
K, 3, 5/2+d, 3.5/2+d,0 !定义建立模型的关键点3
K, 4, 5/2+d,-3.5/2-d,0 !定义建立模型的关键点4
A, 1,2,3,4 !由关键点形成面
!分出基层
voffst,1,3.66,0
wpoffs,0,0,-0.21
vsbw,all
!分出底基层
wpoffs,0,0,-0.2
vsbw,all
!分出垫层及土基
wpoffs,0,0,-0.25
vsbw,all
!分出扩大基础
wpoffs,0,0,0.65
wpoffs,-5/2,0,0
wprota,0,0,90
vsbw,all
wpoffs,0,0,5
vsbw,all
wprota,0,90,0
wpoffs,0,0,1.75
vsbw,all
wpoffs,0,0,-3.5
vsbw,all
!生成面层
asel,s,loc,z,0
asel,r,loc,x,-5/2,5/2
asel,r,loc,y,-3.5/2,3.5/2
vext,all,,,0,0,0.25 !伸展面

allsel
vplot

!选择边划分单元
lsel,s,loc,z,-0.66,-3.66
lsel,r,length,,2.5
lesize,all,0.5

lsel,s,loc,z,-0.41,-0.66
lsel,r,length,,0.25
lesize,all,0.1

lsel,s,loc,z,-0.2,-0.41
lsel,r,length,,0.2
lesize,all,0.1

lsel,s,loc,z,0,-0.2
lsel,r,length,,0.2
lesize,all,0.05

lsel,s,loc,z,0.25,0
lsel,r,length,,0.25
lesize,all,0.05

lsel,s,loc,z,0.25,-3.66
lsel,r,loc,y,-3.5/2-d, 3.5/2+d
lsel,r,loc,x,-5/2, 5/2
lsel,r,length,,5
lesize,all,0.1

lsel,s,loc,z,0.25,-3.66
lsel,r,loc,x,-5/2-d, 5/2+d
lsel,r,loc,y,-3.5/2, 3.5/2
lsel,r,length,,3.5
lesize,all,0.1

lsel,s,loc,z,0.25,-3.66
lsel,r,length,,d
lesize,all,0.4

!划分面层
vsel,s,loc,z,0,0.25
vplot
type,1
mat,1
vmesh,all
!划分水稳基层
vsel,s,loc,z,0,-0.21
vplot
type,1
mat,2
vmesh,all
!划分二灰基层
vsel,s,loc,z,-0.21,-0.41
vplot
type,1
mat,3
vmesh,all
!划分碎石基层
vsel,s,loc,z,-0.41,-0.66
vplot
type,1
mat,4
vmesh,all
!划分土基
vsel,s,loc,z,-0.66,-3.66
vplot
type,1
mat,5
vmesh,all


!选择节点
nsel,s,,,all

!对底面施加固定约束
nsel,s,loc,z,-3.66
d,all,all,0
!约束面层y方向位移为零
nsel,s,loc,y,3.5/2
nsel,r,loc,z,0,0.25
d,all,uy,0
nsel,s,loc,y,-3.5/2
nsel,r,loc,z,0,0.25
d,all,uy,0
!约束面层x方向位移为零
nsel,s,loc,x,5/2
nsel,r,loc,z,0.25,0
d,all,ux,0
nsel,s,loc,x,-5/2
nsel,r,loc,z,0.25,0
d,all,ux,0
!约束路基和基层y方向位移为零
nsel,s,loc,y,3.5/2+d
nsel,r,loc,z,-3.66,0
d,all,uy,0
nsel,s,loc,y,-3.5/2-d
nsel,r,loc,z,-3.66,0
d,all,uy,0
!约束路基和基层x方向位

移为零
nsel,s,loc,x,5/2+d
nsel,r,loc,z,-3.66,0
d,all,ux,0
nsel,s,loc,x,-5/2-d
nsel,r,loc,z,-3.66,0
d,all,ux,0

!选择所有结点
nsel,s,,,all


!施加荷载两个轮胎
nsel,s,loc,z,0.25
nsel,r,loc,x,-0.2,0.2
nsel,r,loc,y,3.5/2,3.5/2-0.2
sf,all,pres,0.625e6

!施加荷载另外两个轮胎
nsel,s,loc,z,0.25
nsel,r,loc,x,-0.2,0.2
nsel,r,loc,y,3.5/2-1.8,3.5/2-2.0
sf,all,pres,0.625e6


!选择所有结点
nsel,s,,,all
finish



/solu
!设置求解精度
EQSLV,PcG,1E-6
solve
finish