EXCEL统计函数汇集分类

DCOUNT： 返回数据库或数据清单的列中满足指定条件并且包含数字的单元格个数。
DCOUNTA： 返回数据库或数据清单的列中满足指定条件的非空单元格个数
COUNT： 返回所选区域中包含数字的单元格的个数.
COUNTA： 返回所选区域中非空白单元格的个数.
COUNTBLANK：返回所选区域中空白单元格的个数.
COUNTIF： 计算区域中满足给定条件的单元格的个数.
FREQUENCY： 以一列垂直数组返回某个区域中数据的频率分布.

数组公式： 当上面的函数不能满足条件计数的需要时，可以使用数组公式来实现计数要求.

VBA： 编写特定的宏也可以满足计数的要求。
COUNTIFS* 返回满足多个条件的单元格数量
DCOUNT 计算满足给定条件的数据库记录的字段(列)中数字单元格数量
DCOUNTA 计算满足指定条件的数据库中记录字段(列)的非空单元格数量
DEVSQ 返回各数据点与数据均值点之差(数据偏差)的平方和，主要用于统计公式中
FREQUENCY 计算数值在某个区域内的出现频率，然后返回一个垂直数组。只适用于多数组公式
SUBTOTAL 当第一个参数为2、3、102或103时，返回包含分类汇总的单元格数量，当第一个参数为9或109时，返回包含分类汇总的单元格数值之和
SUM 返回参数之和
SUMIF 返回满足指定条件的单元格之和
SUMIFS* 返回满足一组条件的单元格之和
SUMPRODUCT 将两个或多个区域相应的单元格相乘，然后返回乘积之和
SUMSQ 返回所有参数的平方和，主要用于统计公式中
SUMX2PY2 返回两个区域中对应数值平方和之和，主要用于统计公式中
SUMXMY2 返回两个区域中对应数值之差的平方和，主要用于统计公式中
SUMX2MY2 返回两个区域中对应数值的方差之和，主要用于统计公式中



其实，一个COUNTIF函数都可以解决了：

一、求各种类型单元格的个数

(1) 求真空单元格单个数: =COUNTIF(data,"=")

(2) 真空+假空单元格个数: =COUNTIF(data,"") 相当于countblank()函数

(3) 非真空单元格个数: =COUNTIF(data,"<>") 相当于counta()函数

(4) 文本型单元格个数: =COUNTIF(data,"*") 假空单元格也是文本型单元格

(5) 区域内所有单元格个数: =COUNTIF(data,"<>""")

(6) 逻辑值为TRUE的单元格数量 =COUNTIF(data,TRUE)

小说明：

EXCEL单元格内数据主要有以下几类:数值型,文本型,逻辑型,错误值型。其中时间类型也是一种特殊的数值。文本类型的数字是文本型。

空单元格：指什么内容也没有的单元格，姑且称之为真空。

假空单元格：指0字符的空文本，一般是由网上下载来的或公式得来的，姑且称之为假空。

date指单元格区域，该参数不能是数组

二、求><=某个值的单元格个数

(1) 大于50 =COUNTIF(data,">50")

(2) 等于50 =COUNTIF(data,50)

(3) 小于50 =COUNTIF(data,"<50")

(4) 大于或等于50 =COUNTIF(data,">=50")

(5) 小于或等于50 =COUNTIF(data,"<=50")

(6) 大于E5单元格的值 =COUNTIF(data,">"&$E$5)

(7) 等于E5单元格的值 =COUNTIF(data,$E$5)

(8) 小于E5单元格的值 =COUNTIF(data,"<"&$E$5)

(9) 大于或等于E5单元格的值 =COUNTIF(data,">="&$E$5)

(10) 小于或等于E5单元格的值 =COUNTIF(data,"<="&$E$5)

三、等于或包含某N个特定字符的单元格个数

(1) 两个字符 =COUNTIF(data,"??")

(2) 两个字符并且第2个是B =COUNTIF(data,"?B")

(3) 包含B =COUNTIF(data,"*B*")

(4) 第2个字符是B =COUNTIF(data,"?B*")

(5) 等于“你好” =COUNTIF(data,"你好")

(6) 包含D3单元格的内容 =COUNTIF(data,"*"&D3&"*")

(7) 第2字是D3单元格的内容 =COUNTIF(data,"?"&D3&"*")


注：countif()函数对英文字母不区分大小写，通配符只对文本有效

四、两个条件求个数

(1) >10并且<=15 =SUM(COUNTIF(data,">"&{10,15})*{1,-1})

(2) >=10并且<15 =SUM(COUNTIF(data,">="&{10,15})*{1,-1})

(3) >=10并且<=15 =SUM(COUNTIF(data,{">=10",">15"})*{1,-1})

(4) >10并且<15 =SUM(COUNTIF(data,{">10",">=15"})*{1,-1})

注：一般多条件计数使用SUMPRODUCT函数，以上方法较少使用，仅供参考。

补充：三个区域计数：

三个区域中>=60 =SUM(COUNTIF(INDIRECT({"a46:a48","b48:b50","c47:c48"}),">=60"))

五、各种特殊统计要求的计算 A2：A32 为存放数据的区域

（1）非空文本（仅包括可键入文本） =COUNTIF(A2:A32,">=!")

（2）所有非空文本 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ") 或 {=SUM(COUNTIF(A2:A32,">="&{"!"," "})*{1,-1})+COUNTIF(A2:A32,">="&CHAR(1))}

（3）全部可见单元格 {=SUM(N(IF(ISERROR(A2:A32),1,SUBSTITUTE(A2:A32," ",""))<>""))}

（4）有效可见单元格 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")+COUNT(A2:A32)

（5）全部不见单元格（真空＋空格＋空文本） =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">= ")

（6）空格 =COUNTIF(A2:A32,">= ")-COUNTIF(A2:A32,">=!")

（7）空文本"" =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,"=")

更多参考 https://www.wendangku.net/doc/aa4550931.html,。