ansys拓扑优化形状优化实例1

FINISH
/CLEAR,START
/TRIAD,OFF !关闭整体直角坐标系的三角符号
H=1000 !设置比例尺，采用iso
TK16=6.35/H !设置参数变量并附初值
TK27=6.35/H
TK38=6.35/H
TK49=6.35/H
TK50=4/H
/PREP7
ET,1,PLANE42
MP,EX,1,6.89E10
MP,NUXY,1,0.3
K,1
K,5,254/H
KFILL ! 在第1至第5个关键点之间生成2,3,4关键点
K,6,,TK16
K,7,63.5/H,TK27
K,8,127/H,TK38
K,9,190.5/H,TK49
K,10,254/H,TK50
SPLINE,6,7,8,9,10
L,1,6
*REPEAT,5,1,1 !重复L命令，关键点编号自动加1，分别在2,7、3,8、4,9、5,10之间共生成4条线其中包含了、命令已生成的线，共5条
LSEL,S,LINE,,5,9 !选择上述生成的5条线
LESIZE,ALL,,,1 !指定线在划分网格前的等分数为1
LSEL,ALL
A,1,2,7,6
*REPEAT,4,1,1,1,1 !重复上述命令，共生成4个面
ESIZE,,4
AMESH,ALL
FINISH
/SOLU
NSEL,S,LOC,Y
DSYM,SYMM,X !对选择的节点施加x方向的对称约束
NSEL,S,LOC,X
DSYM,ASYM,Y !对选择的节点施加x方向的反对称约束
NSEL,ALL
FK,10,FX,66725*4 !在10号关键点施加集中载荷，实现弯矩
DK,1,ALL,0 !在1号关键点施加全约束
SOLVE
FINISH
/POST1
SET,LAST
ETABLE,EVOL,VOLU !建立单元表，并取出每个单元的体积EVOL=每个单元的体积
PRNSOL,S,PRIN !列出节点的主应力
NSORT,S,1
NSEL,U,LOC,X,0,230/H !选择介于0到230/H的节点
*GET,STRS,SORT,,MAX !取出最大的应力值并赋给strs
NSEL,ALL
SSUM !体积相加
*get,TVOL,ssum,,item,EVOL !取出结构总体积
TVOL=TVOL*2 !由于分析时只计算了结构的一半，总体积要乘2
NSEL,U,LOC,X,250/H,265/H !选择介于250/H到265/H的节点
PRNSOL,U,Y !列表显示出所选节点在y向的位移值
NSORT,U,Y,,1 !位移值升序排列
PRNSOL,U,Y !列出排序后的结果
*GET,DEFL,SORT,,MAX !取出最大的位移值赋给defl
*STATUS,PARM !显示当前参数变量的状态值
DEFL=ABS(DEFL)
DIF1=TK16-TK27 !设置参数值，以保证曲线的光滑性
DIF2=TK27-TK38
DIF3=TK38-TK49
FINISH
lgwrite,scratch,lgw
/OPT
opanl,scratch,lgw !指定分析文件
opvar,TVOL,Obj,,,1/H !定义优化目标函数,收敛误差为1，结构总体积TVOL为目标函数
opvar,STRS,sv,,206E6 ! 定义状态变量即优化过程的约束条件
opvar,DEFL,sv,,12.5/H
opvar,DIF1,sv,,1/H
opvar,DIF2,sv,,1/H
opvar,DIF3,sv,,1/H
opvar,TK16,dv,4/H,7/H !定义第一个设计变量及其变化范围
opvar,TK27,dv,4/H,7/H
opvar,TK38,dv,4/H,7/H
opvar,TK49,dv,4/H,7/H
opsave,INITIAL,opt !保存所有的优化数据到文件optp里
optype,SUBP !设置优化方式,子问题逼近算法
OPSUBP,30 !指定迭代次数
opexe ! 执行优化
PARSAV,,RSET1 !将参数的值输出到文件中且文件名为rset1
oplist,all,,1 !列表显示所有序列
/AXLAB,Y,TVOL !设置曲线输出时y轴的说明
plvaropt,TVOL

!绘图显示目标函数随优化次数的变化规律
FINISH

/POST1
PLNSOL,U,SUM,0,1 !显示结构在优化后的总位移分布
PLNSOL,S,EQV,0,1 !显示结构在优化后的应力分布
FINISH